# prompt style and colors based on Steve Losh's Prose theme:
 # http://github.com/sjl/oh-my-zsh/blob/master/themes/prose.zsh-theme
 #
 # vcs_info modifications from Bart Trojanowski's zsh prompt:
 # http://www.jukie.net/bart/blog/pimping-out-zsh-prompt

 #
 # git untracked files modification from Brian Carper:
 # http://briancarper.net/blog/570/git-info-in-your-zsh-prompt

 
 function virtualenv_info {
     [ $VIRTUAL_ENV ] && echo '('`basename $VIRTUAL_ENV`') '
 }
 PR_GIT_UPDATE=1
 
 setopt prompt_subst
 autoload colors
 colors
 
 autoload -U add-zsh-hook
 autoload -Uz vcs_info
 
 

 # enable VCS systems you use
 zstyle ':vcs_info:*' enable git svn
 

 # check-for-changes can be really slow.
 # you should disable it, if you work with large repositories
 zstyle ':vcs_info:*:prompt:*' check-for-changes true
 
 # set formats
 # %b - branchname
 # %u - unstagedstr (see below)
 # %c - stagedstr (see below)
 # %a - action (e.g. rebase-i)
 # %R - repository path
 # %S - path in the repository
 PR_RST="%{${reset_color}%}"
 FMT_BRANCH="(%{$fg[magenta]%}%b%u%c${PR_RST})"
 FMT_ACTION="(%{$fg[green]%}%a${PR_RST})"

 FMT_UNSTAGED="%{$fg[yellow]%}●"
 FMT_STAGED="%{$fg[green]%}●"

 
 zstyle ':vcs_info:*:prompt:*' unstagedstr   "${FMT_UNSTAGED}"
 zstyle ':vcs_info:*:prompt:*' stagedstr     "${FMT_STAGED}"
 zstyle ':vcs_info:*:prompt:*' actionformats "${FMT_BRANCH}${FMT_ACTION}"
 zstyle ':vcs_info:*:prompt:*' formats       "${FMT_BRANCH}"
 zstyle ':vcs_info:*:prompt:*' nvcsformats   ""
 
 
 function steeef_preexec {
     case "$(history $HISTCMD)" in
         *git*)
             PR_GIT_UPDATE=1
             ;;

         *svn*)
             PR_GIT_UPDATE=1
             ;;

     esac
 }
 add-zsh-hook preexec steeef_preexec
 
 function steeef_chpwd {
     PR_GIT_UPDATE=1
 }
 add-zsh-hook chpwd steeef_chpwd
 
 function steeef_precmd {

     # check for untracked files or updated submodules, since vcs_info doesn't

     if [[ -n $(git ls-files --other --exclude-standard 2> /dev/null) ]]; then

         PR_GIT_UPDATE=1
         FMT_BRANCH="(%{$fg[magenta]%}%b%u%c%{$fg[red]%}●${PR_RST})"
     else
         FMT_BRANCH="(%{$fg[magenta]%}%b%u%c${PR_RST})"
     fi
     zstyle ':vcs_info:*:prompt:*' formats       "${FMT_BRANCH}"
 

     if [[ -n "$PR_GIT_UPDATE" ]] ; then
         vcs_info 'prompt'
         PR_GIT_UPDATE=
     fi
 }
 add-zsh-hook precmd steeef_precmd
 
 PROMPT=$'
 %{$fg[magenta]%}%n%{$reset_color%} at %{$fg[yellow]%}%m%{$reset_color%} in %{$fg_bold[green]%}%~%{$reset_color%} $vcs_info_msg_0_
 $(virtualenv_info)$ '