# Check for updates on initial load...

 if [ "$DISABLE_AUTO_UPDATE" != "true" ]

 then

   /usr/bin/env ZSH=$ZSH zsh $ZSH/tools/check_for_upgrade.sh

 fi
 

 # Initializes Oh My Zsh
 

 # add a function path

 fpath=($ZSH/functions $ZSH/completions $fpath)

 # Load all of the config files in ~/oh-my-zsh that end in .zsh
 # TIP: Add files you don't want in git to .gitignore

 for config_file ($ZSH/lib/*.zsh) source $config_file

 # Set ZSH_CUSTOM to the path where your custom config files
 # and plugins exists, or else we will use the default custom/
 if [[ -z "$ZSH_CUSTOM" ]]; then
     ZSH_CUSTOM="$ZSH/custom"
 fi
 

 # Add all defined plugins to fpath. This must be done
 # before running compinit.

 plugin=${plugin:=()}

 for plugin ($plugins); do
   if [ -f $ZSH_CUSTOM/plugins/$plugin/$plugin.plugin.zsh ]; then
     fpath=($ZSH_CUSTOM/plugins/$plugin $fpath)
   elif [ -f $ZSH/plugins/$plugin/$plugin.plugin.zsh ]; then
     fpath=($ZSH/plugins/$plugin $fpath)
   fi
 done

 # Load and run compinit
 autoload -U compinit
 compinit -i

 # Load all of the plugins that were defined in ~/.zshrc

 for plugin ($plugins); do

   if [ -f $ZSH_CUSTOM/plugins/$plugin/$plugin.plugin.zsh ]; then
     source $ZSH_CUSTOM/plugins/$plugin/$plugin.plugin.zsh

   elif [ -f $ZSH/plugins/$plugin/$plugin.plugin.zsh ]; then

     source $ZSH/plugins/$plugin/$plugin.plugin.zsh
   fi
 done
 

 # Load all of your custom configurations from custom/

 for config_file ($ZSH_CUSTOM/*.zsh) source $config_file

 # Load the theme

 if [ "$ZSH_THEME" = "random" ]
 then
   themes=($ZSH/themes/*zsh-theme)
   N=${#themes[@]}

   ((N=(RANDOM%N)+1))

   RANDOM_THEME=${themes[$N]}
   source "$RANDOM_THEME"
   echo "[oh-my-zsh] Random theme '$RANDOM_THEME' loaded..."
 else

   if [ ! "$ZSH_THEME" = ""  ]
   then
     source "$ZSH/themes/$ZSH_THEME.zsh-theme"
   fi

 fi